El tutorial muestra cómo usar IF junto con la función AND en Excel para verificar múltiples condiciones en una sola fórmula.
Algunas cosas en el mundo son finitas. Otros son infinitos, y la función IF parece ser una de esas cosas. Ya tenemos un puñado de tutoriales de Excel IF en nuestro blog y seguimos descubriendo nuevos usos todos los días. Hoy veremos cómo puede usar IF junto con la función AND para evaluar dos o más condiciones al mismo tiempo.
Declaración IF AND en Excel
Para construir la declaración IF AND, obviamente necesita combinar las funciones IF y AND en una sola fórmula. Así es cómo:
SI Y (condición 1, condición 2,…), valor_si_verdadero, valor_si_falso)
Traducido al inglés simple, la fórmula dice lo siguiente: SI la condición 1 es verdadera Y la condición 2 es verdadera, haz una cosa, de lo contrario haz otra cosa.
Por ejemplo, hagamos una fórmula que verifique si B2 se «entregó» y C2 no está vacío y, según los resultados, realice una de las siguientes acciones:
- Si ambas condiciones son VERDADERAS, marque el pedido como «Cerrado».
- Si cualquiera de las condiciones es FALSO o ambas son FALSO, entonces devuelve una cadena vacía («»).
=IF(AND(B2="delivered", C2<>""), "Closed", "")
La siguiente captura de pantalla muestra la función IF AND en Excel:
Si desea devolver un valor si la prueba lógica se evalúa como FALSO, proporcione ese valor en el archivo valor_si_falso argumento. P.ej:
=IF(AND(B2="delivered", C2<>""), "Closed", "Open")
La fórmula modificada muestra «Cerrado» si la columna B es «entregada» y C tiene algún dato (no vacío). En todos los demás casos, devuelve «Abierto»:
Nota. Cuando utilice una fórmula IF AND en Excel para evaluar las condiciones del texto, tenga en cuenta que las letras mayúsculas y minúsculas se tratan como el mismo carácter. Si estás buscando un fórmula IF AND sensible a mayúsculas y minúsculasincluya uno o más argumentos AND en la función EXACTA como en el ejemplo vinculado.
Ahora que conoce la sintaxis de la instrucción IF AND de Excel, permítame mostrarle qué tipo de tareas puede realizar.
Excel SI: mayor que Y menor que
En el ejemplo anterior, estábamos probando dos condiciones en dos celdas diferentes. Pero a veces es posible que necesite ejecutar dos o más pruebas en la misma celda. Un ejemplo típico es verificar si el valor de una celda es entre dos números. ¡La función IF AND de Excel también puede hacer eso fácilmente!
Supongamos que tiene algunos números de ventas en la columna B y se le pide que informe montos superiores a $50 pero inferiores a $100. Para hacer esto, ingrese esta fórmula en C2 y luego cópiela en la columna:
=IF(AND(B2>50, B2<100), "x", "")
Si debe incluir valores límite (50 y 100), utilice Menos que o igual a operador (<=) y Mayor qué o igual a (>=) operador:
=IF(AND(B2>=50, B2<=100), "x", "")
Para procesar otros valores límite sin cambiar la fórmula, ingrese los números mínimo y máximo en dos celdas separadas y haga referencia a esas celdas en su fórmula. Para que la fórmula funcione correctamente en todas las filas, asegúrese de usar el límite absoluto de referencias de celda ($ F$1 y $F$2 en nuestro caso):
=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")
Usando una fórmula similar, puede verificar si un Fecha caer dentro de un rango especificado.
Por ejemplo, marquemos las fechas entre el 10 de septiembre de 2018 y el 30 de septiembre de 2018, inclusive. Un pequeño obstáculo es que los datos no se pueden enviar directamente a las pruebas lógicas. Para que Excel entienda los datos, debe incluirse en la función DATEVALUE, así:
=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")
O simplemente escriba de y a datos en dos celdas ($F$1 y $F$2 en este ejemplo) y «sáquelos» de esas celdas usando la ya conocida fórmula IF AND:
=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")
Para obtener más información, consulte la declaración IF de Excel entre dos números o fechas.
SI esto Y eso, entonces calcula algo
Además de devolver valores predefinidos, la función SI Y de Excel también puede realizar diferentes cálculos dependiendo de si las condiciones especificadas son VERDADERAS o FALSAS.
Para demostrar el enfoque, calcularemos una bonificación del 5 % para las ventas «cerradas» de $100 o más.
Suponiendo que el monto está en la columna B y el estado del pedido en la columna C, la fórmula es la siguiente:
=IF(AND(B2>=100, C2="closed"), B2*10%, 0)
La fórmula anterior asigna cero al resto de los comandos (valor_si_falso = 0). Si está dispuesto a dar una pequeña bonificación de incentivo, digamos un 3 %, a los pedidos que no cumplan las condiciones, incluya la ecuación adecuada en valor_si_falso argumento:
=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)
Más sentencias IF AND en Excel
Como habrás notado, solo evalué dos criterios en todos los ejemplos anteriores. Pero no hay nada que le impida incluir tres o más pruebas en sus fórmulas IF AND, siempre que respeten estas limitaciones generales de Excel:
- En Excel 2007 y versiones posteriores, se pueden usar hasta 255 argumentos en una fórmula, con una longitud total de fórmula que no supere los 8192 caracteres.
- En Excel 2003 y versiones anteriores, no se permiten más de 30 argumentos, con una longitud total que no supere los 1024 caracteres.
Como ejemplo de varias condiciones AND, tenga en cuenta lo siguiente:
- El monto (B2) debe ser mayor o igual a $100
- El estado del pedido (C2) es «Cerrado»
- La fecha de entrega (D2) está en el mes actual
Ahora, necesitamos una declaración IF AND para identificar las órdenes para las cuales las 3 condiciones son VERDADERAS. Y aquí está:
=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")
Dado que el «mes actual» en el momento de escribir este artículo era octubre, la fórmula da los siguientes resultados:
Declaraciones IF AND anidadas
Cuando trabaje con hojas de trabajo grandes, es posible que deba verificar varios conjuntos de diferentes criterios AND simultáneamente. Para hacer esto, tome una fórmula IF anidada clásica de Excel y extienda las pruebas lógicas con declaraciones AND, como esta:
SI Y(…), salida1SI Y(…), salida 2SI Y(…), salida3, salida4)))
Para tener una idea general, observe el siguiente ejemplo.
Suponiendo que desea calificar su servicio según el costo de envío y el tiempo estimado de entrega (ETD):
- Excelente: Costo de envío por debajo de 20 USD y ETD por debajo de 3 días
- Pobre: Costo de envío superior a USD 30 y ETD superior a 5 días
- Promedio: cualquier cosa en el medio
Para terminar, escribe dos declaraciones IF AND individuales:
IF(AND(B2<20, C2<3), "Excellent", …)
IF(AND(B2>30, C2>5), "Poor", …)
…y se acurrucan el uno en el otro:
=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))
El resultado será similar a esto:
Se pueden encontrar más ejemplos de fórmulas en declaraciones IF AND anidadas en Excel.
Función IF AND sensible a mayúsculas y minúsculas en Excel
Como se mencionó al comienzo de este tutorial, las fórmulas IF AND de Excel no distinguen entre mayúsculas y minúsculas porque la función AND no distingue entre mayúsculas y minúsculas.
si trabajas con distingue mayúsculas y minúsculas data y desea evaluar las condiciones AND teniendo en cuenta el caso del texto, realice cada prueba lógica individualmente dentro de la función EXACTA y coloque esas funciones en su instrucción AND:
SI (Y (EXACTAMENTEcelúla,»condición 1«, EXACTO(celúla,»condición 2«)), valor_si_verdadero, valor_si_falso)
Para este ejemplo, marcaremos los pedidos de un cliente específico (por ejemplo, la empresa llamada ciberespacio) con una cantidad que exceda un cierto número, digamos $100.
Como puede ver en la captura de pantalla a continuación, algunos nombres de empresas en la columna B muestran el mismo extracto del caso del personaje y, sin embargo, son empresas diferentes, por lo que debemos verificar los nombres. exacto. Las sumas en la columna C son números, y realizamos una prueba regular de «mayor que» en ellos:
=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")
Para que la fórmula sea más flexible, puede ingresar el nombre y el monto del cliente objetivo en dos celdas separadas y hacer referencia a esas celdas. No olvide bloquear las referencias de celda con el signo $ ($G$1 y $G$2 en nuestro caso) para que no cambien cuando copie la fórmula en otras filas:
=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")
Ahora, puede ingresar cualquier nombre y cantidad en las celdas de referencia, y la fórmula señalará los comandos correspondientes en su tabla:
HACER O TAMBIÉN fórmula en Excel
En las fórmulas IF de Excel, no está limitado a usar una sola función lógica. Para verificar varias combinaciones de múltiples condiciones, puede combinar IF, AND, OR y otras funciones para ejecutar las pruebas lógicas necesarias. Aquí hay un ejemplo de una fórmula IF AND OR que prueba algunas condiciones AND. Y ahora, te mostraré cómo puedes hacer dos o más pruebas AND dentro de la función OR.
Supongamos que desea marcar los pedidos de dos clientes con una cantidad superior a un número determinado, digamos $100.
En lenguaje Excel, nuestras condiciones se expresan de la siguiente manera:
OR(AND(Customer1, Amount>100), AND(Customer2, Amount>100)
Suponiendo que los nombres de los clientes están en la columna B, las cantidades en la columna C, los 2 nombres objetivo están en G1 y G2, y la cantidad objetivo está en G3, use esta fórmula para marcar las órdenes correspondientes con una «x»:
=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")
Los mismos resultados se pueden lograr con una sintaxis más compacta:
=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")
¿No estás seguro de entender completamente la lógica de la fórmula? Se puede encontrar más información en Excel IF con múltiples condiciones AND/OR.
Así es como usa las funciones IF y AND juntas en Excel. ¡Gracias por leer y nos vemos la próxima semana!
Cuaderno de ejercicios para practicar
SI Y Excel – ejemplos de fórmulas (archivo .xlsx)
