El tutorial explica cómo usar múltiples IF en Excel y proporciona algunos ejemplos de fórmulas If anidadas para las tareas más comunes.
Si alguien te preguntara qué función de Excel usas con más frecuencia, ¿cuál sería tu respuesta? En la mayoría de los casos, es la función IF de Excel. Una fórmula If regular que prueba una sola condición es muy simple y fácil de escribir. Pero, ¿qué sucede si sus datos requieren pruebas lógicas más elaboradas con más condiciones? En este caso, puede incluir múltiples funciones IF en una sola fórmula y estas múltiples declaraciones If se llaman SI anidado de Excel. La mayor ventaja de la instrucción If anidada es que le permite verificar más de una condición y devolver diferentes valores según los resultados de esas comprobaciones, todo en una fórmula.
Microsoft Excel tiene límites para niveles FI anidados. En Excel 2003 y anteriores, se permitían hasta 7 niveles. En Excel 2007 y versiones posteriores, puede anidar hasta 64 funciones SI en una sola fórmula.
Más adelante en este tutorial, encontrará varios ejemplos de declaraciones If de Excel anidadas, junto con una explicación detallada de su sintaxis y lógica.
Ejemplo 1. Fórmula IF anidada clásica
Aquí hay un ejemplo típico de un Excel If con múltiples condiciones. Suponga que tiene una lista de estudiantes en la columna A y sus puntajes de examen en la columna B, y desea clasificar los puntajes con las siguientes condiciones:
- Excelente: más de 249
- Bueno: Entre 249 y 200, inclusive
- Satisfactorio: Entre 199 y 150 inclusive
- Pobre: por debajo de 150
Y ahora, escribamos una función SI anidada basada en los criterios anteriores. Se considera una buena práctica comenzar con la condición más importante y mantener sus funciones lo más simples posible. Nuestra fórmula IF anidada de Excel es la siguiente:
=IF(B2>249, "Excellent", IF(B2>=200, "Good", IF(B2>150, "Satisfactory", "Poor")))
Y funciona exactamente como debería:
Comprender la lógica IF anidada de Excel
Escuché a algunas personas decir que Excel múltiple If los vuelve locos 🙂 Intente verlo desde un ángulo diferente:
Lo que la fórmula realmente le dice a Excel que haga es evaluar prueba_logica de la primera función SI y, si se cumple la condición, devolver el valor proporcionado en valor_si_verdadero argumento. Si no se cumple la condición de la primera función If, pruebe la segunda declaración If y así sucesivamente.
SI(comprobar si B2>=249, si es cierto – volver «Excelente», o
SI(comprobar si B2>=200, si es cierto – volver «Bien», o
SI(comprobar si B2>150, si es cierto – volver «Satisfactoriamente», si es falso –
devolver «Pobre»)))
Ejemplo 2. Múltiples If con cálculos aritméticos
Aquí hay otra tarea típica: el precio unitario varía según la cantidad especificada, y su objetivo es escribir una fórmula que calcule el precio total para cualquier cantidad de artículos ingresados en una celda determinada. En otras palabras, su fórmula debe verificar varias condiciones y realizar diferentes cálculos según el rango de cantidades en el que se encuentra la cantidad especificada:
| Cantidad unitaria | Precio por unidad |
| 1 a 10 | $20 |
| 11 a 19 | $18 |
| 20 a 49 | $16 |
| 50 a 100 | $13 |
| más de 101 | $12 |
Esta tarea también se puede realizar mediante el uso de múltiples funciones IF. La lógica es la misma que en el ejemplo anterior, la única diferencia es que multiplica la cantidad especificada por el valor devuelto por los IF anidados (es decir, el precio por unidad correspondiente).
Suponiendo que el usuario ingresa la cantidad en la celda B8, la fórmula es la siguiente:
=B8*IF(B8>=101, 12, IF(B8>=50, 13, IF(B8>=20, 16, IF( B8>=11, 18, IF(B8>=1, 20, "")))))
Y el resultado será algo como esto:
Como comprenderá, este ejemplo solo demuestra el enfoque general y puede personalizar fácilmente esta función If anidada de acuerdo con su tarea particular.
Por ejemplo, en lugar de «codificar» los precios en la fórmula, puede hacer referencia a las celdas que contienen esos valores (celdas B2 a B6). Esto permitirá a los usuarios editar los datos de origen sin tener que actualizar la fórmula:
=B8*IF(B8>=101,B6, IF(B8>=50, B5, IF(B8>=20, B4, IF( B8>=11, B3, IF(B8>=1, B2, "")))))
O bien, es posible que desee incluir una función IF adicional que establezca los límites superior, inferior o ambos del rango de suma. Cuando la cantidad está fuera de rango, la fórmula mostrará un mensaje «fuera de rango». P.ej:
=IF(OR(B8>200,B8<1), "Qty. out of range", B8*IF(B8>=101,12, IF(B8>=50, 13, IF(B8>=20, 16, IF( B8>=11, 18, IF(B8>=1, 20, ""))))))
Las fórmulas IF anidadas descritas anteriormente funcionan en todas las versiones de Excel. En Excel 365 y Excel 2021, también puede usar la función IFS para el mismo propósito.
Los usuarios avanzados de Excel que están familiarizados con las fórmulas de matriz pueden usar esta fórmula que básicamente hace lo mismo que la función IF anidada discutida anteriormente. Aunque la fórmula de matriz es mucho más difícil de entender, y mucho más de escribir, tiene una ventaja innegable: especifica el rango de celdas que contienen sus condiciones, en lugar de hacer referencia a cada condición individualmente. Esto hace que la fórmula sea más flexible, y si sus usuarios cambian alguna de las condiciones existentes o agregan una nueva, solo necesitará actualizar una referencia de rango en la fórmula.
IF anidado de Excel – Consejos y trucos
Como acaba de ver, no hay ciencia espacial para usar múltiples IF en Excel. Los siguientes consejos lo ayudarán a mejorar sus fórmulas IF anidadas y evitar errores comunes.
Límites de FI anidados
En Excel 2007 – Excel 365, puede anidar hasta 64 funciones IF. En versiones anteriores de Excel 2003 y anteriores, se pueden usar hasta 7 funciones IF anidadas. Sin embargo, el hecho de que pueda incluir muchas IF en una fórmula no significa que deba hacerlo. Tenga en cuenta que cada nivel adicional hace que su fórmula sea más difícil de entender y depurar. Si su fórmula tiene demasiados niveles anidados, es posible que desee optimizarla utilizando una de estas alternativas.
El orden de las funciones IF anidadas es importante
La función IF anidada de Excel evalúa las pruebas lógicas en el orden en que aparecen en la fórmula, y tan pronto como una de las condiciones se evalúa como VERDADERO, las condiciones subsiguientes no se prueban. En otras palabras, la fórmula se detiene después del primer resultado VERDADERO.
Veamos cómo funciona en la práctica. Con B2 igual a 274, la siguiente fórmula IF anidada evalúa la primera prueba lógica (B2>249) y devuelve «Excelente» porque esta prueba lógica es VERDADERA:
=IF(B2>249, "Excellent", IF(B2>=200, "Good", IF(B2>150, "Satisfactory", "Poor")))
Ahora invirtamos el orden de las funciones SI:
=IF(B2>150, "Satisfactory", IF(B2>200, "Good", IF(B2>249, "Excellent", "Poor")))
La fórmula prueba la primera condición, y dado que 274 es mayor que 150, el resultado de esta prueba lógica también es VERDADERO. En consecuencia, la fórmula devuelve «Satisfecho» sin probar otras condiciones.
Verá, cambiar el orden de las funciones IF cambia el resultado:
Evaluar la lógica de la fórmula.
Para seguir el flujo lógico de la fórmula IF anidada paso a paso, use la función Evaluar fórmula ubicada en Fórmula pestaña, en Auditoría de fórmula grupo. La expresión subrayada es la parte que se evalúa y en la que se hace clic para evaluar El botón le mostrará todos los pasos del proceso de evaluación.
Por ejemplo, la evaluación de la primera prueba lógica de la fórmula IF anidada que se muestra en la siguiente captura de pantalla procederá de la siguiente manera: B2>249; 274>249; VERDADERO; Excelente.
Equilibrar el soporte de funciones IF anidadas
Uno de los principales desafíos con los IF anidados en Excel es hacer coincidir los pares de paréntesis. Si los paréntesis no coinciden, la fórmula no funcionará. Afortunadamente, Microsoft Excel ofrece algunas funciones que pueden ayudarlo a equilibrar los paréntesis al editar una fórmula:
- Si tiene más de un conjunto de paréntesis, los pares de paréntesis se sombrean en diferentes colores para que el paréntesis de apertura coincida con el paréntesis de cierre.
- Cuando cierra un paréntesis, Excel resalta brevemente el par coincidente. El mismo efecto de negrita o «parpadeo» se produce cuando se desplaza por la fórmula con las teclas de flecha.
Para obtener más información, consulte Coincidencia de pares de paréntesis en fórmulas de Excel.
Trata el texto y los números de manera diferente
Al crear pruebas lógicas de fórmulas IF anidadas, recuerde que el texto y los números deben tratarse de manera diferente: siempre incluya los valores de texto entre comillas dobles, pero nunca ponga comillas alrededor de los números:
Bien: =SI(B2>249, «Excelente»,…)
Equivocado: =SI(B2>»249″, «Excelente»,…)
La prueba lógica de la segunda fórmula devolverá FALSO incluso si el valor en B2 es mayor que 249. ¿Por qué? Porque 249 es un número y «249» es una cadena de números, que son dos cosas diferentes.
Agregue espacios o saltos de línea para que los IF anidados sean más fáciles de leer
Al crear una fórmula con varios niveles IF anidados, puede aclarar la lógica de la fórmula separando las diferentes funciones IF con espacios o saltos de línea. A Excel no le importa el espacio adicional en una fórmula, por lo que no tiene que preocuparse de que se deforme.
Para mover una parte específica de la fórmula a la siguiente línea, haga clic donde desee insertar un salto de línea y presione Alt+Intro. Luego expanda la barra de fórmulas tanto como sea necesario y verá que su fórmula IF anidada se ha vuelto mucho más fácil de entender.
Alternativas al SI anidado en Excel
Para superar el límite de siete funciones SI anidadas en Excel 2003 y versiones anteriores, y para hacer que las fórmulas sean más compactas y rápidas, considere usar las siguientes alternativas a las funciones SI anidadas de Excel.
- Para probar varias condiciones y devolver diferentes valores según los resultados de esas pruebas, puede usar la función SELECCIONAR en lugar de los IF anidados.
- Cree una tabla de búsqueda y use una coincidencia aproximada BUSCARV, como se muestra en este ejemplo: BUSCARV en lugar de IF anidado en Excel.
- Use IF con funciones lógicas OR / AND, como se demuestra en estos ejemplos.
- Use una fórmula de matriz como la que se muestra en este ejemplo.
- Combine varias sentencias IF mediante la función CONCATENAR o el operador de concatenación (&). Puede encontrar una fórmula de ejemplo aquí.
- Para los usuarios avanzados de Excel, la mejor alternativa al uso de varias funciones IF anidadas podría ser crear una función de hoja de cálculo personalizada mediante VBA.
Así es como usa una fórmula If en Excel con múltiples condiciones. Gracias por leer y espero verte en nuestro blog la próxima semana.
Libro de ejercicios para descargar.
Declaraciones anidadas de Excel (archivo .xlsx)
